CivilFEM 梁单元力、弯矩、应力应变的绘制和列表

实例描述

本例中梁截面采取标准30“WF梁(尺寸：W 30×173)，在梁上施加均布荷载荷载，如下图所示，求梁跨中的弯矩、应力和应变。

几何属性

a=10ft=120in

b=20ft=240in

材料属性

钢材 A36 Fy=32 ksi

荷载

w   =   10000 lb/ft = (10000/12) lb/in

分析假定
英尺和 psi(Pounds per square inch磅每平方英尺)用于描述长度和应力单位。使用BEAM3单元建模，因为模型具有对称性，于是之建立一半的模型。

实例命令流

FINISH
~CFCLEAR,,1

! CivilFEM 规范和单位
~UNITS,BIN                   ! in, sg, lbf
~CODESEL,EC3,EC2,,,EC8       ! 欧洲规范: No.3, No.2 and No.8

/PREP7
! CivilFEM 前处理
! --------------------------------------------------
! 定义材料属性
~CFMP,1,LIB,STEEL,ASTM,A36      !材料1: A36 Fy=32 ksi
~CFMP,1,USER
~CFMP,1,EC3,fy,,32000,1,0,0
! 定义单元类型
ET,1,BEAM3
! 定义截面
~SSECLIB,1,1,51,68             ! W 30x173 -> 截面:1
~BMSHPRO,1,BEAM,1,1,,,3,,0,  !钢结构截面，定义梁截面类型
! Ansys前处理
! --------------------------------------------------
! 节点
N,1
N,13,480
FILL,1,13
! 单元
E,1,2
EGEN,12,1,ALL

/SOLU
! Ansys 求解
! --------------------------------------------------
! 约束
D, 4,,,,,,UX,UY
D,10,,,,,,UY
! 荷载
ESEL,S,,, 1, 3,1
ESEL,A,,,10,12,1
SFBEAM,ALL,1,PRES,10000/12
ESEL,ALL
! 求解
SOLVE

/POST1
! CivilFEM 前处理
! --------------------------------------------------
! 读取结果
~CFSET,,1,1
! 绘制力和弯矩
~PLLSFOR,M,Z,-3 ! 弯矩Z
~PLLSFOR,F,Y,-1 ! 剪力Y

! 绘制应力和应变
~PLLSSTR,SX,10,3      ! Y 顶部应力(点 10 位于Y 顶部纤维)
~PLCSSTR,BEAM,6,I,SX  ! 应力在横截面内部
~PLCSSTR,BEAM,6,I,EPX ! 横截面内部的应变

! 列表显示力和弯矩

~PRFOR,BOTH,FY,MZ   ! 两端的FY与MZ(I and J)
! 列表显示应力
~PRSTR,SX,BOTH,POINTS,MINMAX   ! 两个端点的最大值和最小值 (I and J)

~CFSET, ALT, LSTEP, SBSTEP, NSEQ

定义ANSYS数据组并供CivilFEM有选择性地选择一部分ANSYS或CivilFEM数据文件。

ALT：读取文件选择性的数量

• N：可选，其他域内参数被忽略。
  FIRST：可选择的第一个结果文件
  NEXT：下一个可选择的文件
• PREV：前一个寻在的文件
• LAST：最后的结果文件
• LIST：列表显示所有存在的结果文件
• STATUS：显示当前激活的选择

 

LSTEP：读取的荷载步数

SBSTEP：子步数量

NSEQ：可选择步在结果文件存储中的编号

~PLLSFOR, Item, Comp, FACT

绘制力和弯矩

Item：定义显示内容，比如F代表力，M代表弯矩等

Comp：力或弯矩的类别，如轴力、剪力，以及哪个方向的弯矩等

Fact：显示比例

菜单路径

Main Menu > CIVIL Postprocessor > Beam Utilities > Graph Results > Forces and Moments

 

~PLCSSTR, Lab, NUM, KeyIJ, Item

绘制截面内部的应力和弹性应变

Lab：指定图素类型，如beam为梁截面；solsec实体截面

NUM：图素的编号

Keyij：梁单元终点

item：显示的内容，如sx表示x方向应力，sxy表示xy剪应力等

~PRSTR, LabSTR, LabNode, LabTYP, ENTNUM, LabSTR2, LabSTR3, LabSTR4, LabSTR5, LabSTR6

列表显示梁、壳和实体单元截面中的应力和应变

Labstr：显示内容，如sx代表x方向应力等

Labnode：指定是哪个端点，还是两个端点都显示

LabTYP：列表类型，如列表截面点还是列表截面平面

Entnum：LabTYP的下一级参数

菜单路径

Main Menu > CIVIL Postprocessor > Shell Utilities > LIST RESULTS: Stress & Strain

这里可明显看到，在显示结构内力时，CivilFEM比ANSYS Classic更方便，做出来的图形也更直观

在梁截面应力显示上，CivilFEM比ANSYS的栅格点的读取方式便捷得多，注意下面三图是对同一个截面，以Tessella、Point和Plates三个不同方式显示的结果