CivilFEM框架悬挑结构算例

数值模拟 5年前 (2013-01-14) 938 人围观 2

这个实例是官方文档E05ENG.pdf中的第三个例子,在这一例中在多荷载工况的设置上,算是对前两个实例中介绍到的荷载组合做一定的总结。另外,在后处理中,介绍了屈曲分析的计算方法。由于CivilFEM是具有设计功能的专业软件,与ANSYS classic不同的是,它可以用简单的命令直接图形输出结构危险构件的位置和内力大小。

问题描述

框架结构几何尺寸见下图:

数据单位采用国际单位,梁柱尺寸(2 UAP 130/2 UAP 175/IPE 80)以及材料(Steel A42 -EA)均采用西班牙钢结构规范。

分析内容包括:所有构件Y方向弯矩绝对值的最大值;构件X方向轴力绝对值最大值;在对弯矩和轴力考察的基础上,检查结构弯-压屈曲的情况,以及内力包络图分析,进行受力评价。

荷载,分三阶段:

  1. 自重+顶部均布荷载100N/m2
  2. 顶部雪荷载500N/m2
  3. Y方向风荷载,施加到柱和顶部梁,600N/m2

命令流

FINISH
~CFCLEAR,,1
! 总体数据
! --------------------
/VUP,,Z
/VIEW,1,1,1,1
! CivilFEM SETUP
~UNITS,SI
~CODESEL,EC3,EC2,,,EC8
/PREP7
! 2. Materials
! --------------------------------------------------
~CFMP,1,LIB,STEEL,EA,A42
! 3. Elements
! --------------------------------------------------
ET,1,44 ! BEAM44
! 7. MODEL
! --------------------------------------------------
! Nodes
*AFUN,DEG
A=TAN(5)
*AFUN,RAD
HP=2
L=3
WD=2.5
S=SQRT((L*A)**2+L**2)
K,1,0,0,0
K,2,0,0,HP
K,7,L,,HP+(L*A)
KFILL,2,7,4, , ,1
KGEN,2,ALL, , , ,WD, ,7,0 ! Copy Kp
! Lines
L,1,2 ! Column
L,8,9 ! Column
L,2,7 ! Horizontal beam
L,9,14 ! Horizontal beam
*DO,LINE,1,6
L,LINE+1,LINE+8 ! Transverse beams
*ENDDO
! Components generation
! -------------------------
LSEL,S,,,1 $ LSEL,A,,,2
CM,Column,line ! Columns
LSEL,S,,,3 $ LSEL,A,,,4
CM,Horizot,line ! Horizontal beams
LSEL,S,,,5 ! Transverse beams
*DO,I,6,10
LSEL,A,,,I
*ENDDO
CM,Transv,line
! 4. Sections
! --------------------------------------------------
~SSECLIB,1,1,92,3 !2 UAP 130
~SSECLIB,2,1,92,5 !2 UAP 175
~SSECLIB,3,1,1,1 !IPE 80
! 5. Beam & Shell Properties
! --------------------------------------------------
~BMSHPRO,1,BEAM,1,1,,,44,1,0
~BMSHPRO,2,BEAM,2,2,,,44,1,0
~BMSHPRO,3,BEAM,3,3,,,44,1,0
! 6. Member Properties (NECESSARY FOR CODE CHECKING)
! --------------------------------------------------------
!Columns
Prop = 1
L = HP
K = 0.6
KW = 0.5
C1 = 1.0
C2 = 0.0
C3 = 1.0
BETMY = 1
BETMZ = 1
BETMLT = 1
PSI = 0.8
LAT = 0
CFBXY = .75
CFBXZ = .75
CHCKAXIS = 1
~MEMBPRO,Prop,EC3,ALL,L,K,KW,C1,C2,C3,BETMY,BETMZ,BETMLT,PSI,LAT,CFBXY,CFBXZ,CHCKAXIS
!Horizontal beams
Prop = 2
L = 3.0115
K = 0.85
KW = 0.5
C1 = 2
C2 = 0
C3 = 1
BETMY = 1
BETMZ = 1
BETMLT = 1
PSI = 0.8
AH = 0
LAT = 0
CFBXY = 1.5
CFBXZ = 1.5
CHKAXIS = 1
~MEMBPRO,Prop,EC3,ALL,L,K,KW,C1,C2,C3,BETMY,BETMZ,BETMLT,PSI,LAT,CFBXY,CFBXZ,CHCKAXIS
!Transverse beams
Prop = 3
L = WD
K = 1
KW = .5
C1 = 1.2
C2 = 1.2
C3 = 0
BETMY = 1
BETMZ = 1
BETMLT = 1
PSI = 0.8
AH = 0
LAT = 0
CFBXY = 1
CFBXZ = 1
CHKAXIS = 1
~MEMBPRO,Prop,EC3,ALL,L,K,KW,C1,C2,C3,BETMY,BETMZ,BETMLT,PSI,LAT,CFBXY,CFBXZ,CHCKAXIS
! 5. Attributes & Mesh
! --------------------------------------------------
CMSEL,S,Column
REAL,1
ESIZE,0.4 ! Elements of 0.4 m
LMESH, all
CMSEL,S,Horizot
REAL,2
ESIZE,S/5 ! Elements of S/5 m
LMESH, all
CMSEL,S,Transv
REAL,3
ESIZE,0.5 ! Elements of 0.5 m
LMESH, all
ALLSEL
/ESHAPE,1
EPLOT
NUMMRG,NODE,0.001, , ,LOW
/SOLU
! Ansys Solution
! --------------------------------------------------
! DOF restrains
Dk,1, , , , , ,ALL
Dk,8, , , , , ,ALL
!Loads
! -----------
! Self Weight
ACEL,,,9.8
CMSEL,S,Transv
CMSEL,A,Horizot
ESLL,S
Q=100 !100 (N/M2)
SFBEAM,ALL,1,PRES,Q
ALLSEL,ALL
Solve
! Snow Load
ACEL,,,,
SFEDELE,ALL,ALL,PRES
CMSEL,S,Transv
CMSEL,A,Horizot
ESLL,S
S=550 !550 (N/M2)
SFBEAM,ALL,1,PRES,S
ALLSEL,ALL
Solve
!Wind in -Y direction
SFEDELE,ALL,ALL,PRES
W=600
CMSEL,S,Column
LSEL,A,,,4
ESLL,S
SFBEAM,ALL,2,PRES,W
ALLSEL,ALL
Solve
! CivilFEM Combinations
! ---------------------------------------------------------------
/POST1
! Clear previous combinations
~CMBCLR,
! Target definition
! ---------------------------------------------------------------
~TRGDEF,1,CROSS,M,Y,ABS ! Bending moment in Y
~TRGUPT,1,228,S,X ! Stress point definition
~TRGDEF,2,CROSS,SS,PT1,ABS ! Maximum stress
~TRGDEF,3,CROSS,F,X,ABS ! Axial force in X
! Combination No.1:
/TITLE,Snow
! ~CMBDEF, ICMB, TYPE,NSTST
~CMBDEF, 1, ADDVC, 3
! ~STSTDEF,ICMB,ISTST, TYPE ,ITEM1,ITEM2,ITIME,INCSTST,INCITEM1
~STSTDEF, 1, 1,LSTEP,1 ! Self weight
~STSTDEF, 1, 2,LSTEP,2 ! Snow
~STSTDEF, 1, 3,LSTEP,3 ! Wind
! ~STSTDEF,ICMB,ISTST, CFT1, CFT2
~STSTCFT, 1, 1, 1.35, 1.00 ! 1.33 or 1 *Self weight
~STSTCFT, 1, 2, 1.50, 0 ! 1.50 or 0 *Snow
~STSTCFT, 1, 3, 0.9, 0 ! (Fi*1.50)=0.9 or 0*Wind
! Combination No.2:
/TITLE,Wind
! ~CMBDEF, ICMB, TYPE,NSTST
~CMBDEF, 2, ADDVC, 3
! ~STSTDEF,ICMB,ISTST, TYPE ,ITEM1,ITEM2,ITIME,INCSTST,INCITEM1
~STSTDEF, 2, 1,LSTEP,1 ! Self weight
~STSTDEF, 2, 2,LSTEP,2 ! Snow
~STSTDEF, 2, 3,LSTEP,3 ! Wind
! ~STSTDEF,ICMB,ISTST, CFT1, CFT2
~STSTCFT, 2, 1, 1.35, 1.00 ! 1.33 or 1 *Self weight
~STSTCFT, 2, 2, 0.9, 0 ! (Fi*1.50)=0.9 or 0 *Snow
~STSTCFT, 2, 3, 1.50, 0 ! 1.50 or 0 *Wind
! Combination No.3: Envelope
/TITLE,Envolvente
! ~CMBDEF, ICMB, TYPE ,NSTST
~CMBDEF, 3,OPTION, 2
! ~STSTDEF,ICMB,ISTST, TYPE,ITEM1,ITEM2,ITIME,INCSTST,INCITEM1
~STSTDEF, 3, 1,CMB, 1, , 2, 1, 1
! Do combinations
! ---------------------------------------------------------------
~COMBINE,
! Point to combine results
~CMBDAT,2
! Bending moments for combination 3, target 1(envelope)
~CFSET,,3,1
~PLLSFOR,M,Y,-1
! Stresses for combination 3, target 2(envelope)
~CFSET,,3,2
~PLLSSTR,SX,ABS,-2
! Axial load for combination 3, target 3(envelope)
~CFSET,,3,3
~PLLSFOR,F,X,-1
! Check for combination 3 (envelope)
~CFSET,,3,1
~CHKSTL,BUCK_BCM,,full ! Compression+Bending Buckling
~PLLSSTL,ELM_OK
~PLLSSTL,crt_TOT
~CFSET,,3,3
~CHKSTL,BUCK_BCM,,full ! Compression+Bending Buckling
~PLLSSTL,ELM_OK
~PLLSSTL,crt_TOT
!Envelops
~ENVDEF,1,2 !1a and 2a alternatives
~ENVELOP,MAX
~CFSET,3 !Read 3th alternative
~PLLSSTL,ELM_OK
~PLLSSTL,crt_TOT

命令流程总结

  1. 首先定义模型基本参数,包括:选择规范、定义材料、定义单元类型,创建模型几何形状;
  2. 按照各个不同的荷载工况,分别进行加载、求解
  3. 用~CMBCLR命令去除已经定义过的组合
  4. ~TRGDEF:定义组合分析目标
  5. ~CMBDEF:定义组合规则
  6. ~STSTDEF:定义组合规则中的初始条件
  7. ~STSTCFT:设置组合项目的分项系数
  8. 进行荷载组合计算

用到的命令

~CHKSTL, Lab1, ChckAxis, ClassMod, Value1

结构钢截面检查

Lab1

由检查类型确定的Label

ChckAxis

在求解弯矩、轴力等内力时用到的单元轴向.

ClassMod

只在Eurocode 3中应用,定义力和弯矩的计算组

Value1

根据规范设定的数值

举个例子,如果当前规范为欧洲规范,那么Lab1设为TENSION,则进行拉力检查;若为BENDING则为弯矩检查。

~PLLSSTL, Lab1

绘制钢结构梁计算结果,其中ELM_OK为显示结构中的构件是否通过检查,CRT_TOT为Total criterion ,NPLRD为截面的弹性强度等等。