CivilFEM 公路桥梁移动荷载的施加

[文章目录]

模型描述

根据混凝土桥梁移动荷载的作用,找到最大的正负弯矩,得到截面最大正弯矩对应的移动荷载分布。

几何属性

DEPTH   =   1.2 m
BBOT   =   3.5 m
BMID   =   4 m
BTOP   =   7.1 m
TFMIN   =   0.2 m
TFMAX   =   0.4 m
TW   =   0.3 m
TFBOT   =   0.2 m
TFTOP   =   0.2 m
a   =   14 m
b   =   18 m

荷载

荷载包括两个部分:集中荷载和均布荷载。其中,集中荷载模拟双轴共600kN的车辆(组成串联系统),施加在最不利位置;均布荷载为4kN/m2,施加到影响面的最不利部分。

梁单元的网格划分如上图所示。

分析假定

长度单位为m,力单位为kN,模型包括22个beam54单元和22个节点。

命令流

FINISH
~CFCLEAR,,1
! Title
/TITLE, Mobile Loads in a Road Bridge

! CivilFEM Setup:规范和单位
~UNITS,,LENG,M
~UNITS,,TIME,S
~UNITS,,FORC,KN
~CODESEL,EC3,EC2,,,EC8

/PREP7
! CivilFEM Preprocessor
! --------------------------------------------------
! 定义材料
~CFMP,1,LIB,CONCRETE,EC2,C35/45 ! Mat 1: C35/45, gc=1.5, gs=1.15

! 单元类型
ET,1,200,6
ET,2,BEAM54  ! Type 1: 2D 梁
! Ansys Preprocessor 首先自定义梁截面
! --------------------------------------------------
!关键点
K,1,-3.55,0
K,2,-3.55,-0.2
K,3,-2,-0.4
K,4,-1.75,-1.2
K,5,1.75,-1.2
K,6,   2,-0.4
K,7,3.55,-0.1
K,8,3.55,0
A,1,2,3,4,5,6,7,8             ! Create area through points
CYL4,-1.1,-0.6,0.4            ! Create circle
AGEN,3,2, , ,1.1, , ,4,0      ! Copy circle
ASBA,1,2                      ! Subtract areas
ASBA,5,3
ASBA,1,4
!在ANSYS中划分截面网格,并导入到CivilFEM截面库中

MAT,1
TYPE,1
SMRT,6
AMESH,ALL
LOCAL,11,0,0,0,0, , ,-90
~SEC2DIN,1,11                 ! 导入截面
~BMSHPRO,1,BEAM,1,1,,,54,1,0, ! 实常数

! 清除截面,建立梁节点
CSYS,0
ACLEAR,2                      ! 删除网格
ADELE,2, , ,1                 ! 删除截面
N,1,0,0 $ N,7,7,0,0 $ N,16,7+9,0,0 $ N,23,7+9+7,0,
FILL, 1,7 $ FILL,7,16 $ FILL,16,23
!创建单元
TYPE,2                        ! Beam 54 element
E,1,2
EGEN,22,1,1
EPLOT

/SOLU
! Ansys Solution
! --------------------------------------------------
! 约束
D,1,UX
D,1,UY
D,7,UY
D,16,UY
D,23,UY

! 荷载步
! 荷载步 1 到23: 600kN集中荷载施加到每个节点
*DO,INODE,1,23    ! 节点循环
F,INODE,FY,-600 ! 施加荷载
SOLVE           ! 求解
FDELE,ALL,ALL   ! 删除荷载
*ENDDO
! 荷载步24到45: 分布荷载(4 kN/m2) 施加到每个单元
*DO,IELEM,1,22
SFBEAM,IELEM,1,PRES,4.0*7.1,4.0*7.1 !施加荷载
SOLVE                               ! 求解
SFEDELE,ALL,ALL,ALL                 ! 删除荷载
*ENDDO

/POST1
! CivilFEM Postprocessor
! --------------------------------------------------

! CivilFEM 组合: 定义目标
~TRGDEF,1,BEAM ,M,Z,MAX   ! 1 : 最大弯矩Maximum bending moment MZ
~TRGDEF,2,CROSS,M,Z,MAX   ! 2 : 最大弯矩MZ (截面)
! CivilFEM 组合:定义组合规则
! 组合规则1: 600 kN 串联系统
! /TITLE,Title
/TITLE,Tandem System 600 kN
! CMBDEF , ICMB, Type      , NSTST, KEYTITL,ITEM1
~CMBDEF ,    1, INCOMPAT,    23
! STSTDEF, ICMB, ISTST, Type  , ITEM1, ITEM2, ITIME, INCSTST,INCITEM1
~STSTDEF,    1,     1,LSTEP  ,     1,      ,    23,       1,       1
! 组合规则2: 均布荷载
! /TITLE,Title
/TITLE,Uniformly Distributed Load
! CMBDEF , ICMB, Type      , NSTST, KEYTITL,ITEM1
~CMBDEF ,    2, COMPATIB,    22
! STSTDEF, ICMB, ISTST, Type  , ITEM1, ITEM2, ITIME, INCSTST,INCITEM1
~STSTDEF,    2,     1,LSTEP,    24,      ,    22,       1,       1
! 组合规则3: 道路交通行为(集中荷载+均布荷载)
/TITLE,Road Traffic Actions
! CMBDEF , ICMB, Type      , NSTST, KEYTITL,ITEM1
~CMBDEF ,    3, ADD     ,     2
! STSTDEF, ICMB, ISTST, Type  , ITEM1, ITEM2, ITIME, INCSTST,INCITEM1
~STSTDEF,    3,     1,  CMB,     1      ! 集中荷载Tandem System 600 kN
~STSTDEF,    3,     2,  CMB,     2      ! 均布荷载
! STSTCFT, ICMB, ISTST, CFT1, CFT2
~STSTCFT,    3,     1, 1.00    ! 集中荷载分项系数= 1.00
~STSTCFT,    3,     2, 1.00    ! 均布荷载分项系数= 1.00
! CivilFEM 组合: 进行组合
~COMBINE,
~CMBDAT,2   !指向组合结果
! CivilFEM 组合: 读取结果
! 最小弯矩Z
~CMB,3,,,,,1              ! 读取组合结果
ETABLE,MZ_i,SMISC,  6     ! ANSYS 单元表 MZ_i
ETABLE,MZ_j,SMISC,  12    ! ANSYS 单元表 MZ_j
PLLS,MZ_i,MZ_j,-3         ! 绘制 ANSYS MZ (可选的缩放因子= -3)
! 最大弯矩Z
~CMB,3,,,,,2            ! 读取组合结果
~PLLSFOR,M,Z,-3         ! 绘制CivilFEM MZ (可选的缩放因子= -3)
! 查询荷载,得到最大弯矩Z出现在15单元,16节点上
~CMBINQ,3,BEAM,M,Z,MAX,16,15,2,1   ! 遍历结果
PLDISP,2                          ! 绘制相伴随的结构变形

 

CivilFEM工况组合的相关命令

定义CF的工况组合,需要几个要素,即目标、规则和运行 。

~TRGDEF, ITRG, Group, Item, Comp, Type

定义目标

ITRG:定义目标的编号

Group:指定目标属于哪个组,可选项如下:

  • BEAM:力、弯矩、应力、应变、组合应变和梁单元的张拉力
  • SHELL:壳单元上的力、弯矩、应力和应变
  • SOLID:2D或3D单元上的应力和应变
  • AXSHL:轴对称板上的力、弯矩、应力和应变
  • DISPL:节点位移和旋转
  • REACT:节点反应
  • CROSS:横截面上的力和弯矩,点上的应力和应变由用户指定。
  • VERTX:壳定点的力、弯矩、应力和应变

Item, Comp:目标识别

Type:识别目标类型的标签

  • MAX:寻找定义数据中的最大值
  • MIN:寻找定义数据中的最小值
  • ABS:寻找定义数据中绝对值最小值

~CMBDEF, ICMB, Type, NSTST, KEYTITL, ITEM1

定义组合规则

ICMB:组合规则编号

Type:组合规则类型

  • ADD:增加初始条件(Add Start States).
  • ADDVC:增加带有可变系数的初始条件
  • INCOMPAT:互不相容或独立的初始条件
  • COMPATIB:兼容,可同时存在的初始条件
  • OPTION:初始条件选项 Option Start States
  • OPPOSED:相反的初始条件
  • SELECT:初始条件选择
  • SELECTVC:带有可变系数的初始条件选择(默认)

NSTST:初始条件数目

KEYTITL:与组合规则名称有关的参数,可设置是否与名称绑定

ITEM1:依赖于组合规则的参数,在类型为SELECT和SELECTVC时,用户指定同时设置的初始条件数目。

菜单路径

Main Menu > Civil Postprocessor > Combine Results > Combination

~STSTDEF, ICMB, ISTST, Type, ITEM1, ITEM2, ITIME, INCSTST, INCITEM1, INCITEM2

定义组合规则中的初始条件

ICMB:初始条件归属的组合规则编号

ISTST:初始条件定义的编号

Type:初始条件类型

  • LSTEP:RST或RCV文件中的荷载步、荷载子步
  • NSET:RST或RCV文件的数据组
  • CMB:CMB或CVMB文件的组合规则
  • DEL:删除初始条件的信息定义

ITEM1, ITEM2:荷载步、数据组或组合规则识别

Type = LSTEP
ITEM1 = Load Step
ITEM2 = Substep

Type = NSET
ITEM1 = Data Set
ITEM2 = Ignored

Type = CMB
ITEM1 = Combination
ITEM2 = Ignored

Type = DEL
ITEM1 = Ignored
ITEM2 = Ignored

ITIME:ISTST 在 INCSTST, ITEM1在INCITEM1以及ITEM2 在INCITEM2中的增长时间

INCSTST:初始条件中的ISTST增长量

INCITEM1:ITEM1增量

INCITEM2:ITEM2增量

菜单路径

Main Menu > Civil Postprocessor > Combine Results > COMBINATIONS: Def Start States

~COMBINE

执行组合

菜单路径

Main Menu > Civil Postprocessor > Combine Results > Combine > Combine for targets

 

~CMBDAT, KEY

指定原始或组合结果

KEY:指定的结果

  • 1:原始结果 (*.RST and *.RCV). 默认值
  • 2:组合结果 (*.CMB and *.CVMB)

 

~CMB, ICMB, Group, Item, Comp, Type, ITRG

载入组合结果

ICMB:组合规则编号,默认为最后一个

Group:目标所属的组

Item:目标项

Comp:目标组合

Type:目标类型

ITRG:目标数量

菜单路径

Main Menu > Civil Postprocessor > Combine Results > READ RESULTS: By Number

Main Menu > Civil Postprocessor > Combine Results > READ RESULTS: By Descript.

Main Menu > Civil Postprocessor > Read Results > READ COMB. DATA: By Number

Main Menu > Civil Postprocessor > Read Results > READ COMB. DATA: By Descript.

~CMBINQ, ICMB, Group, Item, Comp, Type, NODE, ELEM, KEYLIST, KEYCLD, RCItem, RCComp

查询组合结果,关键词含义同上

菜单路径

Main Menu > Civil Postprocessor > Combine Results > INQUIRE: Nodal Results

Main Menu > Civil Postprocessor > Combine Results > INQUIRE: Nodal Results+

Main Menu > Civil Postprocessor > Combine Results > INQUIRE: Element Results

Main Menu > Civil Postprocessor > Combine Results > INQUIRE: Element Results+

*欢迎转载,转载请标明来源:十千牛,文章地址: http://10kn.com/civilfem-mobile-loads-in-a-road-bridge/

欢迎关注十千牛微信公众号

不断加深对结构体系的理解,不断完善描述结构行为的理论与数学模型,不断探测结构真实的受力状态——以此为业,以此为生,以此为乐๑乛◡乛๑

1 条评论

Leave a Reply

Your email address will not be published. Required fields are marked *